/* wind chill formula */
wc: a + b*T + c*v^e + d*T*v^e;

/* wind chill parameters */
vals: [a=35.74, b=0.6215, c=-35.75, d=0.4275, e=0.16];

/* some assumptions */
declare(e,noninteger)$

assume(b * T - T + a > 0, d * T + c < 0)$

/* find T for "wind chill equals temperature" for given v */
Tlimgen: solve([wc = T], [T])[1];

/* insert parameters: limit temperature for given wind speed */
ev(Tlimgen, vals);

/* find v for "wind chill equals temperature" for given T */
vlimgen: solve([wc = T], [v])[1];

/* insert parameters: wind speed limit for given temperature */
vlim: ev(vlimgen, vals);

/* range where wind chill formula is applicable: above the curve */
wxplot2d([part(vlim,2)], [T, 30, 70], [ylabel, v])$

/* Reverse calculation: Find temperatures for two given wind chills */
diffs: solve([wc1 = ev(wc, [T=T1]), wc2 = ev(wc, [T=T2])], [T1, T2])[1];

/* get the difference of those temperatures */
diff: ratsimp(diffs[2] - diffs[1]);

/* insert parameters: find temperature difference for given windchill difference */
ev(diff, vals);